dbhut.com : Snippets : 3D Clock

3D Clock

Description

A real-time 3D clock. I wrote this snippet to demonstrate the 'offset limb' command which allows you to move the rotation centre of an object to somewhere other than the natural centre, in this case the ends of the clock hands.

Gallery

Source Code

Select All ( IE users - code will also be copied to your clipboard )

` Title:    3D Clock
` Author:   Spooky
` Why?:     To demonstrate offset limb command
` Tested:   DBPro with patch 5.1b
` Media:    None required

sync on : sync rate 0 : autocam off

` middle sphere
make object sphere 1,20
color object 1,rgb(255,0,0)

` second hand
make object box 2,2,100,2
color object 2,rgb(0,255,0)
offset limb 2,0,0,50,0

` minute hand
make object box 3,4,80,4
color object 3,rgb(0,0,255)
offset limb 3,0,0,40,0

` hour hand
make object box 4,5,60,5
color object 4,rgb(255,255,0)
offset limb 4,0,0,30,0

` number indicators
for f=0 to 11
   make object sphere f+20,5
   position object f+20,sin(f*30)*110,cos(f*30)*110,0
next f

position camera 0,-80,-200 : point camera 0,-10,0

do
   t$=get time$()
   s=val(right$(t$,2))
   m=val(right$(left$(t$,5),2))
   h=val(left$(t$,2)) : h=(h mod 12)
   zrotate object 2,s*-6.0
   zrotate object 3,(m*-6.0)-(s/10.0)
   zrotate object 4,(h*-30.0)-(m/2.0)
   text 10,10,t$
   sync
loop

"I do not fear computers. I fear the lack of them." - Isaac Asimov.